candelabra := `which candelabra-cli 2>/dev/null || echo ./target/debug/candelabra-cli`
target_dir := justfile_directory() / "target"
tests_dir := justfile_directory() / "tests"
tests_manifest := tests_dir / "Cargo.toml"

export RUST_LOG := "debug"

cost-models: rebuild
  rm -fr {{target_dir}}/candelabra
  @IMPLS=`{{candelabra}} list-library 2>&1 | cut -d ']' -f 2 | grep ::`; for impl in $IMPLS; do just cost-model $impl; done

selections *SELECTFLAGS: rebuild
  @cd tests/ && for i in $(ls -d */); do [ "${i%%/}" == "target" ] || just select ${i%%/} {{SELECTFLAGS}}; done

rebuild:
  which candelabra-cli 2>/dev/null || cargo build
  echo "Candelabra Path: {{candelabra}}"

cost-model impl: (section-start ("cost-model-" + impl)) && (section-end ("cost-model-" + impl))
  {{candelabra}} -l cost-model {{impl}}

select proj *FLAGS: (section-start ("compare-" + proj)) && (section-end ("compare-" + proj))
  {{candelabra}} -l --manifest-path {{tests_manifest}} -p {{proj}} select {{FLAGS}}

profile proj *FLAGS:
  {{candelabra}} --manifest-path {{tests_manifest}} -p {{proj}} select {{FLAGS}}

@section-start NAME:
  echo -e "\e[0Ksection_start:`date +%s`:{{replace(NAME, ":", "-")}}\r\e[0K{{replace(NAME, ":", "-")}}"

@section-end NAME:
  echo -e "\e[0Ksection_end:`date +%s`:{{replace(NAME, ":", "-")}}\r\e[0K"